Title:      "A Backup of Sorts"
Reference:  PC World June 1990
Author:     Glen Briggs
Files:      SORTBAK.DOC, SORTBAK.BAT

DOS's SORT filter is troublesome to use. It requires sending the
program's output to a temporary file, deleting the original, and then
renaming the result. To avoid those steps, use the batch file
SORTBAK.BAT.

Type SORTBAK and the name of a text file to sort alphabetically. The
file can contain anything--names, parts lists, or wine labels from
your cellar. For example, to sort a file named LIST.TXT by the first
letter of each line, enter sortbak list.txt.

SORTBAK.BAT and SORT.EXE must be in the current PATH. SORTBAK uses
RENAME and a temporary file, TEMP.$$$, to sort a file and save the
original contents in $$OLD.FIL. If you sort two files in a row, only
the most recently sorted information is saved. The program displays
instructions and pauses for you to strike a key. This lets you press
<Ctrl>-CY to quit before sorting begins.

--[Cut here]----------------------------------------------------------

echo off
if "%1"=="" goto noFileErr
if not exist %1 goto badFileErr
echo Press Enter to sort %1, or
echo type Ctrl-CY to quit now.
echo After sorting, the original
echo file's contents will be in
echo the file $$OLD.FIL.
echo.
pause
if exist $$old.fil del $$old.fil
sort < %1 > temp.$$$
rename %1 $$old.fil
rename temp.$$$ %1
goto end
:noFileErr
echo Error  : No file named
goto instruct
:badFileErr
echo Error  : File %1 not found
:instruct
echo Syntax : SORTBAK filename
:end
___ Blue Wave/QWK v2.12