echo off
if "%1"=="" goto help
if "%1"=="-" goto reset
if not "%oldpath%"=="" set path=%oldpath%
set oldpath=%path%
set para=%1
:getpara
shift
if "%1"=="" goto setit
set para=%para%;%1
goto getpara
:setit
path=%para%;%path%
set para=
goto end
:reset
if "%oldpath%"=="" goto end
set path=%oldpath%
set oldpath=
goto end
:help
echo AP dir1 [dir2...] : Add a directory to PATH
echo AP -              : Reset to default PATH
:end



Title:      "AP.BAT--The Sequel"
Reference:  PC World March 1990
Author:     Stewart H. C. Hoe
Files:      AP.DOC, AP.BAT

AP.BAT lets you Add Pathnames to the current PATH setting. The batch
file program recognizes multiple directory names and can reset PATH
to its former string each time the program runs. This means you don't
have to run AP twice to remove one temporary path and add another.

Make sure that AP.BAT is in a directory in your path. Then type AP
plus the pathname to add to the current PATH. For example, type AP
C:\TP C:\TC to add those two directories. If you then type AP C:\WP,
the batch file removes the path and adds C:\WP. You can also type AP
alone and press <Enter> to display brief instructions.

If you receive an "Out of environment space" error message when using
AP.BAT, insert a SHELL command in CONFIG.SYS and reboot to expand the
environment. For example, if you boot off of drive C:, you can
reserve 800 bytes of variable space with the line
SHELL=C:\COMMAND.COM C:\ /P /E:800.
___ Blue Wave/QWK v2.12